excel不加班，让你不再因为excel问题而加班。如果你有excel问题不能解决可以私聊我，我将用心替你解决。

函数中最受欢迎的有三大家族，一个是以sum函数为首的求和家族，一个是以vlookup函数为首的查找引用家族，另外一个就是以if函数为首的逻辑函数家族。根据二八定律，学好这三大家族的函数，就能完成80%的工作。

现在一起来学习vlookup函数，让关于查找的烦恼一次全解决！

1、根据番号精确查找俗称。

=vlookup(d2,a:b,2,0)

vlookup函数语法：

=vlookup(查找值,查找区域,返回查找区域第n列,查找模式)

vlookup函数示意图。

2、屏蔽错误值错误值查找。

=vlookup(d2,a:b,2,0)

vlookup函数如果查找不到对应值会显示错误值#n/a，这个看起来很不美观。这时可以在外面加个容错函数iferror，如果是2013版本那就更好，可以用ifna函数，这个是专门处理#n/a这种错误值。

=iferror(vlookup(d2,a:b,2,0),"")

=ifna(vlookup(d2,a:b,2,0),"")

函数语法：

=iferror(表达式,错误值要显示的结果)

说白了就是将错误值显示成你想要的结果，不是错误值就返回原来的值。ifna函数的作用也是一样，只是iferror函数是针对所有错误值，而ifna函数只针对#n/a。

3、按顺序返回多列对应值。

通过上面的例子，我们知道可以通过更改第3参数，返回各项对应值如：

=vlookup($a13,$a$1:$f$10,2,0)

=vlookup($a13,$a$1:$f$10,3,0)

如果项目少，更改几次参数也没什么，但项目多时，肯定不方便。如图5?103所示，可以通过row、lumn产生行列号，从而得到1，2，……，n的值。

=vlookup($a13,$a$1:$f$10,lumn(b1),0)

因为这里是同一行产生序号，所以用lumn函数。

4、按不同顺序返回对应值。

 

这回看来只能手动更改第3参数了，lumn完全派不上用场。

no！每当你觉得操作繁琐时，就要停下来思考，也许excel本身存在这个功能，只是自己一时想不到或者不知道而已。列号不管千变万化，在数据源的位置始终不变，利用这个特点可以去搜索一下看看有什么函数可以解决。

在“搜索函数”文本框输入：位置，单击“转到”按钮，就会出现跟位置有关的函数，查看每个函数的说明，找到我们需要的，如match函数，返回符合特定值特定顺序的项在数组中的相应位置，单击“确定”按钮。

在弹出的“函数参数对话框”中尝试填写相应的参数，每个参数的作用下面都有相关说明，填写后会出现计算结果3，也就是订单数在区域中是第3列。尝试下更改第1参数为c12（俗称），计算结果是2，也就是区域中第2列。经过尝试，知道这个函数是我们要找的那个函数，单击“取消”按钮，返回工作表。

在单元格再做最后一次验证。

到这一步已经十拿九稳了，将公式设置为：

=vlookup($a13,$a$1:$f$10,match(b$12,$a$1:$f$1,0),0)

5、根据番号逆序俗称。

帮助提到vlookup函数只能按首列查找，不能逆向查找，既然如此，那就得想办法将非首列的区域转换成首列。怎么转换区域呢，这时if函数就派上用场。一步步来了解if函数的转换。

看看好友传递如何趣聊if函数，吃货的福音。

if函数其实只有一个条件来判断是否符合条件，返回false和true两种结果。

当菜只有分甜的或咸的2种口味时，甜味是红烧肉，咸味是酱油肉。

盲人吃饭时，看不到是什么菜。当别人问盲人：“你现在吃的什么菜？是咸的吗？如果是咸的，就是酱油肉，如果不是咸的就是红烧肉。”（给定判断条件：咸味）盲人刚好在吃红烧肉，于是就咂吧着嘴说：“恩，好吃，不是咸的！是红烧肉”（根据提问的要求，不符合咸的）假如要是盲人当时是在吃酱油肉呢,一定回答；“是的，咸的，是酱油肉”（条件为真，是！true）。盲人根据口感，结合提问者说的条件，就知道自己吃的是红烧肉还是酱油肉了。

把这段话用公式来写：

=if(a1="咸的",a2,b2)

翻译：是咸的吗？要是（true），就是酱油肉，要是不是咸的（false），就是甜的红烧肉。

a1="咸的"这个条件也可以直接换成true或者false。

=if(true,a2,b2)

因为满足条件，所以返回a2的对应值酱油肉。

=if(false,a2,b2)

因为不满足条件，所以返回b2的对应值红烧肉。

其实true=1，false=0，所以可以直接用1跟0表示。

=if(1,a2,b2)

=if(0,a2,b2)

if函数不止可以返回1个单元格的值，也可以返回多个单元格的值。

=if({1,0},a2,b2)

=if({0,1},a2,b2)

选择两个单元格输入，按ctrl+shift+enter三键结束。条件为{1,0}，返回a2:b2的对应值顺序不变；条件为{0,1}，返回a2:b2的对应值，顺序对换。也就是说通过改变1跟0的位置，可以调换两单元格的前后位置。

看到这里，知道if函数通过改变1,0可以调换单元格的顺序，如果要改变区域的顺序也是可以实现的。

用if函数重新构造的新区域，是多单元格数组公式，记得按ctrl+shift+enter三键结束，否则出错。

新区域：

=if({1,0},b2:b10,a2:a10)

所以公式可以变成：

=vlookup(a13,新区域,2,0)

两个公式合并，大功告成。

=vlookup(a13,if({1,0},$b$2:$b$10,$a$2:$a$10),2,0)

6、根据俗称跟订单号两个条件查询完成情况。

正常情况下vlookup函数是不能多条件查询，通过if函数的学习，我们知道if函数可以重新构造区域，这里就再次用if构成一个区域。

新区域：

=if({1,0},a2:a9&c2:c9,e2:e9)

所以公式可以变成：

=vlookup(a12&b12,新区域,2,0)

两个公式合并，大功告成，记得按ctrl+shift+enter三键结束。

=vlookup(a12&b12,if({1,0},$a$2:$a$9&$c$2:$c$9,$e$2:$e$9),2,0)

7、根据俗称的第一个字符查找番号。

=vlookup(d2&"*",a:b,2,0)

星号（*）是通配符，代表所有字符，问号（?）代表一个字符。d2&"*"就是开头包含d2的意思。

8、根据区域判断成绩的等级。

借助辅助列的话，很容易查询等级，只需将vlookup函数的第四参数设置为1或者省略即可。

=vlookup(e2,a:c,3)

如果不用辅助列，估计很多人看到这条公式就得哭了，得结合前面所有函数知识才能完成，有兴趣的朋友可以自己去研究。

=vlookup(e2,if({1,0},--left(b$2:b$5,find("-",b$2:b$5)-1),c$2:c$5),2)

前阵子无意间发现了imreal函数，所以不用辅助列的数组公式可以稍微简单一点。

=vlookup(e2,if({1,0},imreal(b$2:b$5&"i"),c$2:c$5),2)

imreal函数是计算复数的实部系数的函数，作用就是提取区间的下限。

通过这8个疑难，基本上的查询问题都能够解决。

开心吗？一下搞定8大疑难！

延伸阅读：

惊呆了!公司报销的加油费都超过出租车了,税务都查出来了!用发票发补贴的企业一定要看!

VLOOKUP函数滚一边去,我才是Excel真正的查找之王!

【汇算清缴实务】一个被99%人忽视的调整项目,您做对了吗?